blob: af2c82f7bd9024094470a443d46dfc3381862ec8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
/* SPDX-License-Identifier: GPL-2.0 */
ENTRY(__efistub_efi_zboot_header);
PROVIDE(zboot_code_size = ABSOLUTE(0));
SECTIONS
{
.head : ALIGN(4096) {
*(.head)
}
.text : {
*(.text* .init.text*)
}
.rodata : ALIGN(8) {
__efistub__gzdata_start = .;
*(.gzdata)
__efistub__gzdata_end = .;
*(.rodata* .init.rodata* .srodata*)
. = ALIGN(4);
__efistub_code_size = .;
LONG(zboot_code_size);
_etext = ALIGN(4096);
. = _etext;
}
.data : ALIGN(4096) {
*(.data* .init.data*)
_edata = ALIGN(512);
. = _edata;
}
.bss : {
*(.bss* .init.bss*)
_end = ALIGN(512);
. = _end;
}
/DISCARD/ : {
*(.discard .discard.*)
*(.modinfo .init.modinfo)
}
}
PROVIDE(__efistub__gzdata_size =
ABSOLUTE(__efistub__gzdata_end - __efistub__gzdata_start));
PROVIDE(__data_rawsize = ABSOLUTE(_edata - _etext));
PROVIDE(__data_size = ABSOLUTE(_end - _etext));
|
